Office Manager Entwickler-Support

Inventor CAD-Zeichnungen verarbeiten

Die Skripte automatisieren den Office Manager und den Autodesk-Inventor. Beide Programme müssen also installiert sein.
Siehe auch Dokumentation der Zeichnungsverwaltung.

Nur im 32 Bit-Office Manager möglich, weil "Windows Script Host" nur für 32 Bit-Software verfügbar ist.

1. iProperties aus Inventor in das Zeichnungsarchiv übernehmen

Die iProperties werden aus der Zeichnungsdatei gelesen und die entsprechenden Datenfelder im Archiv aktualisieren.
Skript inventor-read-iproperties.vbs:

' Office Manager-Script zum Auslesen der Inventor iProperties mittels COM
' Die iProperties werden in die Felder des Zeichnungsarchives übernommen
' Inventor muss auf dem PC installiert sein
' (c) Softwarebüro Krekeler 08.11.2010, mail@krekeler.de

' Initialisierung...
const cIDSummaryInformation = "{F29F85E0-4FF9-1068-AB91-08002B27B3D9}"
const cIDocSummaryInformation = "{D5CDD502-2E9C-101B-9397-08002B2CF9AE}"
const cIDUserDefinedProperties = "{D5CDD505-2E9C-101B-9397-08002B2CF9AE}"
const cIDDesignTracking = "{32853F0F-3444-11D1-9E93-0060B03C1CA6}"
dim invpropset
dim invprop
dim tmpstr

' Office Manager-Dataset zuweisen...
set omappl = CreateObject("om.OfficeManagerApp")
set omds = omappl.Archive.DatasetDocument
DocFileName = omds.GetFieldValue("FILENAME")

' Inventor-Dokument öffnen...
set invappl = CreateObject("Inventor.Application")
set invdoc = invappl.documents.open(DocFileName)

' für Tests: alle Properties auflisten...
' for each invpropset in invdoc.PropertySets
'   MsgBox "Propertyset Name: " & invpropset.InternalName
'   for each invprop in invpropset
'     MsgBox "Property: " & invprop.Name & " = " & invprop.Value
'   Next
' Next

'-------------------------------------------------------------------------------

' omds.Edit auskommentieren, wenn sich die Archivdatenbank während dem Import
' im Modus bereits dsEdit befindet
omds.Edit

' Propertyset "Inventor Summary Information"...
' set invpropset = invdoc.PropertySets.Item(cIDSummaryInformation)

' Propertyset "Inventor Document Summary Information"...
' set invpropset = invdoc.PropertySets.Item(cIDocSummaryInformation)

' Propertyset "Inventor User Defined Properties"...
' set invpropset = invdoc.PropertySets.Item(cIDUserDefinedProperties)

' Propertyset Design Tracking...
set invpropset = invdoc.PropertySets.Item(cIDDesignTracking)

' links stehen die Feldnamen des Archives, rechts die Namen der iProperties
omds.SetFieldValue "USERNAME", invpropset.Item("Designer").Value
omds.SetFieldValue "DOCNO", invpropset.Item("Part Number").Value
omds.SetFieldValue "NAME", invpropset.Item("Description").Value
omds.SetFieldValue "PROJECT", invpropset.Item("Project").Value
' Sonderfall Status: Inventor gibt die Nummer des Eintrages zurück
tmpStr = invpropset.Item("Design Status").Value
if tmpStr = "1" then
  omds.SetFieldValue "STATE", "In Bearbeitung"
elseif tmpStr = "2" then
  omds.SetFieldValue "STATE", "Unerledingt"
else
  omds.SetFieldValue "STATE", "Freigegeben"
end if

' EIGENE FELDER DEFINIEREN:
' omds.SetFieldValue "OM interner Feldname", invpropset.Item("Inventor interner Feldname").Value
' Beispiele für weitere Felder. Das Datenfeld muss im Zeichnungsarchiv vorhanden sein
' omds.SetFieldValue "CREATEDATE", invpropset.Item("Creation Time").Value
' omds.SetFieldValue "NUMBER2", invpropset.Item("Stock Number").Value
' omds.SetFieldValue "ZCHNGINDEX", invpropset.Item("Standard Revision").Value

' omds.Post auskommentieren, wenn während Import bereits dsEdit ist
omds.Post

'-------------------------------------------------------------------------------
' aufräumen...
set omds = Nothing
set omappl = Nothing
set invprop = Nothing
set invpropset = Nothing
set invdoc = Nothing
invappl.Quit
set invappl = Nothing
 

2. iProperties in die Inventor-Zeichnung schreiben

Änderungen, die innerhalb des Office Managers an den Archiv-Datenfeldern vorgenommen wurden, werden in die Inventor-Zeichnungsdatei geschrieben. Hiermit kann beispielsweise der Schriftkopf aktualisiert werden.

Siehe Skript inventor-write-iproperties.vbs

 

Die Skripte in der Zeichnungsverwaltung installieren

Für eine manuelle Installation wählen Sie bitte im Office Manager-Menü Ansicht | Optionen | Dokumenttyp und fügen Sie die Skripte auf der Seite Befehle hinzu.

Zur automatischen Einrichtung schieben Sie bitte folgende Links zu den Toolup-Dateien mit der Maus (Drag&Drop) auf die Dokumententabelle und wählen Sie den Befehl (Dateiname).omini installieren. Sie können die Dateien auch auf Ihre Festplatte speichern und dann per Drag&Drop installieren. Diese zweite Methode funktioniert auch mit Office Manager-Version älter 12.0.3.468.

Weitere Ressourcen

Autodesk: Using iProperties with Inventor VBA (englisch)